Запросы к метаданным

К сожалению, в платформе 1С8 нет возможности выполнять запросы к метаданным.

А при анализе конфигурации порой хочется получить список всех справочников или всех реквизитов документов, которые содержат определенный тип.

Для таких целей программисты обычно пишут обход дерева метаданных.

Я тоже так раньше делал, но потом написал универсальную функцию обхода дерева.

Она не слишком шустрая, т.к. использует команду «Выполнить» для отбора результата, но в таких задачах шустрость не всегда нужна.

Вот код функции, обходящей метаданные:

Функция ОбойтиМетаданные(П, Код)

//Обходит метаданные, выбирая код отбора...

МДКласc=Новый Массив();

МДКласc.Добавить("РегистрыСведений");

МДКласc.Добавить("Константы");

МДКласc.Добавить("Справочники");

МДКласc.Добавить("Документы");

МДКласc.Добавить("РегистрыБухгалтерии");

МДКласc.Добавить("РегистрыНакопления");

МДКласc.Добавить("РегистрыРасчета");

МДКласc.Добавить("Перечисления");

МДКласc.Добавить("Отчеты");

МДКласc.Добавить("Обработки");

МДКласc.Добавить("ЖурналыДокументов");

МДКласc.Добавить("ПланыВидовХарактеристик");

МДКласc.Добавить("ПланыСчетов");

МДКласc.Добавить("БизнесПроцессы");

МДКласc.Добавить("Задачи");

МДКласc.Добавить("ПланыВидовРасчета");

ТЗ=Новый ТаблицаЗначений();

ТЗ.Колонки.Добавить("Класс");

ТЗ.Колонки.Добавить("Вид");

//ТЗ.Колонки.Добавить("Реквизит");

ТЗ.Колонки.Добавить("Атрибут");

ТЗ.Колонки.Добавить("ТипАтрибута");

ТЗ.Колонки.Добавить("ВидАтрибута");

ТЗ.Колонки.Добавить("Синоним");

ТЗ.Колонки.Добавить("Уровень");

П.Вставить("ТЗ", ТЗ);

П.Вставить("Пропустить", ложь);

Для Каждого Класс ИЗ МДКласc Цикл

Описание=Новый Структура();

Описание.Вставить("Класс", Класс);

Описание.Вставить("Уровень", "Класс");

ОбойтиМетаданныеСлуж(П, Описание, Код);

Если П.Пропустить Тогда

Продолжить;

КонецЕсли;

Если Класс="Константы" Тогда

Для Каждого МДАтрибут ИЗ Метаданные.Константы Цикл

Описание=Новый Структура();

Описание.Вставить("Класс", Класс);

Описание.Вставить("Уровень", "Атрибут");

Описание.Вставить("Вид", Неопределено);

Описание.Вставить("Атрибут", МДАтрибут.Имя);

Описание.Вставить("ТипАтрибута", МДАтрибут.Тип);

Описание.Вставить("ВидАтрибута", "Реквизит");

ОбойтиМетаданныеСлуж(П, Описание, Код);

КонецЦикла;

ПродолжитЬ;

КонецЕсли;

Попытка

Для Каждого МДВид ИЗ Метаданные[Класс] Цикл

Описание=Новый Структура();

Описание.Вставить("Класс", Класс);

Описание.Вставить("Вид", МДВид.Имя);

Описание.Вставить("Уровень", "Вид");

Описание.Вставить("Синоним", МДВид.Синоним);

ОбойтиМетаданныеСлуж(П, Описание, Код);

Если П.Пропустить Тогда

Продолжить;

КонецЕсли;

Попытка

Для Каждого МДАтрибут ИЗ МДВид.Реквизиты Цикл

Описание.Вставить("Уровень", "Атрибут");

Описание.Вставить("Атрибут", МДАтрибут.Имя);

Описание.Вставить("Синоним", МДАтрибут.Синоним);

Описание.Вставить("ТипАтрибута", МДАтрибут.Тип);

Описание.Вставить("ВидАтрибута", "Реквизит");

ОбойтиМетаданныеСлуж(П, Описание, Код);

КонецЦикла;

Исключение

КонецПопытки;

Попытка

Для Каждого МДАтрибут ИЗ МДВид.Измерения Цикл

Описание.Вставить("Уровень", "Атрибут");

Описание.Вставить("Атрибут", МДАтрибут.Имя);

Описание.Вставить("Синоним", МДАтрибут.Синоним);

Описание.Вставить("ТипАтрибута", МДАтрибут.Тип);

Описание.Вставить("ВидАтрибута", "Измерение");

ОбойтиМетаданныеСлуж(П, Описание, Код);

КонецЦикла;

Исключение

КонецПопытки;

Попытка

Для Каждого МДАтрибут ИЗ МДВид.Ресурсы Цикл

Описание.Вставить("Уровень", "Атрибут");

Описание.Вставить("Атрибут", МДАтрибут.Имя);

Описание.Вставить("Синоним", МДАтрибут.Синоним);

Описание.Вставить("ТипАтрибута", МДАтрибут.Тип);

Описание.Вставить("ВидАтрибута", "Ресурс");

ОбойтиМетаданныеСлуж(П, Описание, Код);

КонецЦикла;

Исключение

КонецПопытки;

КонецЦикла;

Исключение

КонецПопытки;

КонецЦикла;

Возврат П;

КонецФункции

Функция ОбойтиМетаданныеСлуж(П, Описание, Код)

//обксОбработкаПрерыванияПользователя();

П.Пропустить = ложь;

Р = ложь;

Выполнить(Код);

Если Р = истина Тогда

Стр = П.ТЗ.Добавить();

ЗаполнитьЗначенияСвойств(Стр, Описание);

КонецЕсли;

Возврат Р;

КонецФункции

Параметры функции:

П - это пустая структура, в нее в будет добавлена таблица значений с результатом в поле "ТЗ".

Код - это условие отбора записей из метаданных.

Для функции метаданные представляются как плоская таблица с колонками:

Атрибут - имя реквизита объекта (для уровня "Атрибут")

ТипАтрибута - тип значения реквизита объекта (для уровня "Атрибут")

ВидАтрибута - "Реквизит", "Измерение", "Ресурс" (для уровня "Атрибут")

Синоним - синоним текущего метаданного, если он задан (для уровня "Вид" или "Атрибут")

Уровень - уровень текущей записи, т.е. что описывает текущая запись "Класс", "Вид" или "Атрибут"

Т.е., по сути, метаданные рассматриваются как иерархический справочник с уровнями иерархии: Класс, затем Вид, затем Атрибут.

Выражение для код записывается на языке 1С, где Описание - текущая запись метаданных, если в переменную Р возвращается истина, то осуществляется отбор.

Пример отбора реквизитов, содержащих тип ХранилищеЗначения:

Код = "Р = Описание.Уровень = ""Атрибут"" И Описание.ТипАтрибута.СодержитТип(Тип(""ХранилищеЗначения""))";

Пример получения списка всех справочников:

Код = "Р = Описание.Уровень = ""Вид"" И Описание.Класс = "Справочники";

Запрос к метаданным использован также в следующих моих разработках:

· Граббер картинок

· Проверка размера данных в хранилищах значений

· Анализ прав доступа

Конечно, обработку можно ускорить, избавиться от Выполнить, но пока и в таком виде она неплохо справляется.

Как видно, не все объекты метаданных поддерживаются, например, нет бизнес-процессов, но основные типы есть, остальные можно прикрутить. ;-)

Будут идеи - пишите, а может берите, и подтачивайте под свои нужды, а потом шлите мне исправления. Если что, опубликую.